Commit 9ae7757e authored by Matt Clarkson's avatar Matt Clarkson

Issue #1: Continuous[Build|Test] not needed.

parent 035d41ad
Pipeline #4072 failed with stages
in 18 seconds
@echo off
rem The script is invoked from the gitlab-ci.yml job without arguments.
rem The script assumes that the following environment variables are set:
rem
rem - srcdir: points to the scikit-surgerygpucpp source folder
rem - sbdir: points to the folder where scikit-surgerygpucpp is to be built (superbuild folder)
rem
rem The script also assumes that the current directory is %sbdir%
rem
rem The script builds scikit-surgerygpucpp in release mode with testing on.
rem Enable command extensions to allow checking exit status of commands.
setlocal EnableExtensions
set "VS_DIR=C:\Program Files (x86)\Microsoft Visual Studio\2017\Community"
set "CMAKE_DIR=C:\Program Files\CMake"
rem Allowed values of BTYPE are "x64" and "Win32"
if "%BTYPE%" == "" (
set BTYPE=x64
)
if "%BTYPE%" == "x64" (
set "CMAKE_GENERATOR=Visual Studio 15 2017 Win64"
call "%VS_DIR%\VC\Auxiliary\Build\vcvarsall.bat" x86_amd64
) else (
set "CMAKE_GENERATOR=Visual Studio 15 2017"
call "%VS_DIR%\VC\Auxiliary\Build\vcvarsall.bat" x86
)
set GIT_SSL_NO_VERIFY=1
set "VS_COMMAND=devenv.com"
echo Visual Studio folder: %VS_DIR%
echo Visual Studio command: %VS_COMMAND%
echo CMake folder: %CMAKE_DIR%
echo Source folder: %srcdir%
echo Build folder: %sbdir%
echo CMake generator: %CMAKE_GENERATOR%
rem stop visual studio recycling already running instances of msbuild.exe. we want clean ones.
rem http://stackoverflow.com/questions/12174877/visual-studio-2012-rtm-has-msbuild-exe-in-memory-after-close
set MSBUILDDISABLENODEREUSE=1
set BCONF=Release
set "VS_CONF=%BCONF%^|%BTYPE%"
echo Visual Studio config: %VS_CONF%
set CL=/D_CRT_SECURE_NO_DEPRECATE /D_CRT_NONSTDC_NO_DEPRECATE
set LINK=/LARGEADDRESSAWARE
rem The git usr/bin directory is needed for the 'tee' command.
set "PATH=%CMAKE_DIR%\bin;C:\Program Files\Git\usr\bin;%VS_DIR%\Common7\IDE;%PATH%"
echo PATH: %PATH%
@echo on
call cmake.exe ^
-DCMAKE_BUILD_TYPE:STRING=%BCONF% ^
-DBUILD_SUPERBUILD:BOOL=ON ^
-DBUILD_Boost:BOOL=ON ^
-DBUILD_Python_Boost:BOOL=ON ^
-DBUILD_OpenCV:BOOL=OFF ^
-DBUILD_Eigen:BOOL=OFF ^
-DBUILD_ArrayFire:BOOL=OFF ^
-DBUILD_TESTING:BOOL=ON ^
-DSKSURGERYGPUCPP_USE_CUDA:BOOL=OFF ^
-DSKSURGERYGPUCPP_CUDA_ARCH_BIN:STRING=30 ^
--config "%BCONF%" ^
-G "%CMAKE_GENERATOR%" "%srcdir%"
if %ERRORLEVEL% NEQ 0 exit /B 1
%VS_COMMAND% /build %BCONF% /project ALL_BUILD /projectconfig %VS_CONF% %sbdir%/SKSURGERYGPUCPP-SuperBuild.sln | tee %sb_dir%/build.log 2>&1
if %ERRORLEVEL% NEQ 0 exit /B 2
@echo off
rem The script is invoked from the gitlab-ci.yml job without arguments.
rem The script assumes that the following environment variables are set:
rem
rem - src_dir: points to the source folder
rem - sb_dir: points to the superbuild folder
rem
rem The script also assumes that the current directory is %sb_dir%
rem
rem The script runs the test for a scikit-surgerygpucpp release mode build.
rem Enable command extensions to allow checking exit status of commands.
setlocal EnableExtensions
set "CMAKE_DIR=C:\Program Files\CMake"
echo CMake folder: %CMAKE_DIR%
echo Project build folder: %pb_dir%
set BCONF=Release
cd /d "%pb_dir%"
setlocal EnableDelayedExpansion
if defined CUDA_PATH (
set PATH=%PATH%;%CUDA_PATH%/bin
)
echo PATH: %PATH%
@echo on
"%CMAKE_DIR%/bin/ctest.exe" -S CTestContinuous.cmake -V
if %ERRORLEVEL% NEQ 0 exit /B 4
Markdown is supported
0% or
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment